Sparql

.List of Pokemons
[sparql, fields="pokemon,pokemonLabel,pokedexNumber"]
----
SELECT DISTINCT ?pokemon ?pokemonLabel ?pokedexNumber
WHERE
{
    ?pokemon wdt:P31/wdt:P279* wd:Q3966183 .
    ?pokemon p:P1685 ?statement.
    ?statement ps:P1685 ?pokedexNumber;
            pq:P972 wd:Q20005020.
    FILTER (! wikibase:isSomeValue(?pokedexNumber) )
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY (?pokedexNumber)
LIMIT 30
----

.Cats
[sparql, provider="wikidata", fields="item,itemLabel,pic"]
----
SELECT ?item ?itemLabel ?pic
WHERE
{
?item wdt:P31 wd:Q146 .
?item wdt:P18 ?pic
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
LIMIT 10
----

.People who were born in Berlin before 1900
[sparql, provider="dbpedia", fields="name,birth,death,person"]
----
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX : <http://dbpedia.org/resource/>
SELECT ?name ?birth ?death ?person WHERE {
    ?person dbo:birthPlace :Berlin .
    ?person dbo:birthDate ?birth .
    ?person foaf:name ?name .
    ?person dbo:deathDate ?death .
    FILTER (?birth < "1900-01-01"^^xsd:date) .
} ORDER BY ?name
LIMIT 30
----

.Jugadores de Futbol nacidos en Madrid
[sparql, provider="dbpedia", fields='athlete,number']
----
SELECT *
WHERE
{
?athlete a dbo:SoccerPlayer;
dbo:birthPlace [rdfs:label "Madrid"@en];
dbo:number ?number.
}
LIMIT 30
----

[sparql, provider="https://es.dbpedia.org/sparql", fields="torero,cantante"]
----
PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
PREFIX dcterms: <http://purl.org/dc/terms/>
SELECT ?torero ?cantante WHERE{
?torero rdf:type dbpedia-owl:BullFighter .
?torero dbpedia-owl:spouse ?cantante .
?cantante dcterms:subject <http://es.dbpedia.org/resource/Categoría:Cantantes_de_coplas>
}
----